property fileTypes : {¬
    {«class PNGf», ".png"}, ¬
    {JPEG picture, ".jpg"}}

on getType() --判断剪贴板中的数据类型，暂时只支持png和jpg，优先用png
    repeat with aType in fileTypes
        repeat with theInfo in (clipboard info)
            if (first item of theInfo) is equal to (first item of aType) then return aType
        end repeat
    end repeat
    return missing value
end getType

set theType to getType()

if theType is not missing value then
    set filePath to "/Users/viecks/Datas/Blog/octopress/source/images/attaches/" --这里换成你自己放置图片的路径
    set fileName to do shell script "date \"+%Y%m%d%H%M%S\" | md5" --用当前时间的md5值做文件名
    if fileName does not end with (second item of theType) then set fileName to (fileName & second item of theType as text)
    set markdownUrl to "![](http://attaches-mirror.qiniudn.com/images/attaches/" & fileName & ")" --这里如果没有用到图床，就把前面前缀去掉，用到的话换成你自己图床的url
    set filePath to filePath & fileName

    try
        set imageFile to (open for access filePath with write permission)
        set eof imageFile to 0
        write (the clipboard as (first item of theType)) to imageFile -- as whatever
        close access imageFile
        set the clipboard to markdownUrl
        try
            tell application "System Events"
                keystroke "v" using command down
            end tell
        end try
    on error
        try
            close access imageFile
        end try
        return ""
    end try
else
    return ""
end if